libsignal/java/build.gradle

subprojects {
    ext.version_number     = "0.9.8"
    ext.group_info         = "org.whispersystems"

    if (JavaVersion.current().isJava8Compatible()) {
        allprojects {
            tasks.withType(Javadoc) {
                options.addStringOption('Xdoclint:none', '-quiet')
            }
        }
    }
}

task makeJniLibrariesAndroid(type:Exec) {
  group 'Rust'
  description 'Build the JNI libraries'

  commandLine './build_jni.sh', 'android'
}

task makeJniLibrariesDesktop(type:Exec) {
  group 'Rust'
  description 'Build the JNI libraries'

  commandLine './build_jni.sh', 'desktop'
}

task cargoClean(type:Exec) {
  group 'Rust'
  commandLine 'cargo', 'clean'
}

task clean(type: Delete) {
  description 'Clean JNI libs'
  delete fileTree('./android/src/main/jniLibs') {
    include '**/*.so'
  }
  delete fileTree('./java/src/main/resources') {
    include '**/*.so'
    include '**/*.dylib'
    include '**/*.dll'
  }
}
clean.dependsOn(cargoClean)

task makeAll() {
  group 'Rust'
  description 'Build the native libraries'

  dependsOn 'makeJniLibrariesDesktop', 'makeJniLibrariesAndroid'
}